@echo off
goto top
:help
cls
echo  ** XTCON - CONFIGURATION QUICK-SELECTOR FOR XTREE GOLD 2.5 and 3.0 **
echo.
echo  "Xtcon" starts Xtree with any of 7 selectable configuration files
echo  (Xtgold.cfg), for different screen colours, editors, log-options etc.
echo.
echo  The DOS utility "Choice.com" is required and must be on the DOS path.
echo.
echo  Xtree is started from Xtcon by selecting a configuration.  Changes made
echo  within Xtree to this configuration may later be saved as an update to
echo  that configuration option by re-running Xtcon and choosing Option "S".
echo.
echo  To set up Xtcon:
echo   a) Confirm or change "set xtdir=C:\Xtgold" for correct Xtree directory.
echo   b) Edit the option descriptions A to G to suit your requirements.
echo   c) Create subdirectory "Xtcfgs" off the Xtree directory.
echo   d) Run Xtcon and select a configuration for Xtree.
echo   e) Xtree will start either with the selected configuration if it exists
echo       or the last-used/default if it does not.  Run "configuration"
echo       within Xtree, set up the configuration as required, then quit.
echo   f) Re-run Xtcon and then save the updated configuration via Option S.
echo.
echo  Please use and modify freely.                  Robin Clarke 25 May 1999
echo.
pause
:top
set xtdir=C:\Xtgold
cls
echo.
echo     XTREE CONFIGURATION QUICK-SELECTOR
echo     ~~~~~ ~~~~~~~~~~~~~ ~~~~~ ~~~~~~~~
echo.    Xtree Directory:              %xtdir%
echo     Current Configuration File:   %last%
echo.
echo   GENERAL OPTIONS:
echo.
echo     Q  Quit
echo     H  Help
echo     S  Save configuration file %last% after changes made within Xtree
echo.
echo   CONFIGURATION OPTIONS:
echo.
echo        Configuration File     Description
echo        ~~~~~~~~~~~~~ ~~~~     ~~~~~~~~~~~
echo     A      A.cfg              Standard Xtree Default
echo     B      B.cfg              Description
echo     C      C.cfg              Description
echo     D      D.cfg              Description
echo     E      E.cfg              Description
echo     F      F.cfg              Description
echo     G      G.cfg              Description
echo.
choice /c:QHSABCDEFG ..Choose a Letter:  
if errorlevel 1 set cfg=fin
if errorlevel 2 set cfg=hlp
if errorlevel 3 set cfg=sav
if errorlevel 4 set cfg=A.cfg
if errorlevel 5 set cfg=B.cfg
if errorlevel 6 set cfg=C.cfg
if errorlevel 7 set cfg=D.cfg
if errorlevel 8 set cfg=E.cfg
if errorlevel 9 set cfg=F.cfg
if errorlevel 10 set cfg=G.cfg
echo.
if %cfg%==fin goto end
if %cfg%==hlp goto help
cd %xtdir%
if %cfg%==sav goto save
echo Transferring Configuration File %cfg%
copy %xtdir%\xtcfgs\%cfg% xtgold.cfg
set last=%cfg%
echo.
echo Starting Xtree
xtgold
goto end
:save
echo Updating Configuration File %last%
copy xtgold.cfg %xtdir%\xtcfgs\%last%
goto top
:end